\ Opdracht mozaiektegels maken
\ tegel van 16x16 steentjes bevat 2 kleuren steentjes.
\ 16 steentjes met een accent kleur en 240 met basis kleur
\ steentjes met accent kleur mogen elkaar niet raken ook niet
\ over een tegel heen
\ 
\ 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F
\ 10 11 12 13 14 15 16 17 18 19 1A 1B 1C 1D 1E 1F
\ 20 21 22 23 24 25 26 27 28 29 2A 2B 2C 2D 2E 2F
\ 30 31 32 33 34 35 36 37 38 39 3A 3B 3C 3D 3E 3F
\ 40 41 42 43 44 45 46 47 48 49 4A 4B 4C 4D 4E 4F
\ 50 51 52 53 54 55 56 57 58 59 5A 5B 5C 5D 5E 5F
\ 60 61 62 63 64 65 66 67 68 69 6A 6B 6C 6D 6E 6F
\ 70 71 72 73 74 75 76 77 78 79 7A 7B 7C 7D 7E 7F
\ 80 81 82 83 84 85 86 87 88 89 8A 8B 8C 8D 8E 8F
\ 90 91 92 93 94 95 96 97 98 99 9A 9B 9C 9D 9E 9F
\ A0 A1 A2 A3 A4 A5 A6 A7 A8 A9 AA AB AC AD AE AF
\ B0 B1 B2 B3 B4 B5 B6 B7 B8 B9 BA BB BC BD BE BF
\ C0 C1 C2 C3 C4 C5 C6 C7 C8 C9 CA CB CC CD CE CF
\ D0 D1 D2 D3 D4 D5 D6 D7 D8 D9 DA DB DC DD DE DF
\ E0 E1 E2 E3 E4 E5 E6 E7 E8 E9 EA EB EC ED EE EF
\ F0 F1 F2 F3 F4 F5 F6 F7 F8 F9 FA FB FC FD FE FF

hex

0 value SEED			\ seed voor random generator
10 constant #STEENTJES
10 constant #HOR
10 constant #VER
#hor #ver * constant #PER_TEGEL
#per_tegel 8 /mod swap 0 > abs +	\ afgerond aantal rijen
  constant #MAP
create TEGEL #map allot	\ bitarray voor verdeling steentjes

1B constant ESC
0E value TC		\ tegel kleur
0D value SC		\ steentje kleur
FA value VC		\ voeg kleur
(*
 0 = zwart		 8 = grijs
 1 = rood		 9 = rood
 2 = groen		10 = groen
 3 = geel		11 = geel
 4 = blauw		12 = blauw
 5 = magnenta	13 = magenta 
 6 = cyaan		14 = cyaan
 7 - wit		15 = wit
*) 

: DEFAULT
	ESC emit ch [ emit 30 emit ch m emit
	;
	
: BGC			( kleurnr -- )		\ backgroundcolor
	ESC emit ch [ emit 				\ Esc[48;5;#m
	34 emit 38 emit ch ; emit 35 emit ch ; emit
	dup 64 / 30 + emit 
    64 mod dup A / 30 + emit
	A mod 30 + emit
	ch m emit
	;
	
: RANDOM		( -- r )
	seed 7ABD * 1B0F + dup to seed 	\ bepaal random getal
	FF mod							\ begrens op een tegel
	;
	
: CLRTEGEL		( -- )	\ maak bitarray leeg
	#map 0 ?do
		FF tegel i + *bic
	loop
	;
	
: LOC			( pos -- bit, byte-adr )
	#per_tegel + #per_tegel mod	\ corrigeer voor pos in bitmap
	8 /mod tegel + 				\ bepaal regel (byte-adr)
	swap 1 swap lshift swap		\ bepaal bit in de regel
	;
	 
: VRIJ?			( pos -- flag )	
	\ vierkant rondom en deze positie moet vrij zijn
	\ dat is pos -1 en +1, pos -15, -16 en -17, pos +15, +16 en +17
	>r
	r@ loc bit* 		
	r@ 01 - loc bit* or	
	r@ 0F - loc bit* or	
	r@ 10 - loc bit* or	
	r@ 11 - loc bit* or	
	r@ 01 + loc bit* or	
	r@ 0F + loc bit* or	
	r@ 10 + loc bit* or	
	r@ 11 + loc bit* or	
	0= 					
	rdrop				
	;
	
: ZOEK			( -- pos )	\ zoek geldige pos voor accent steentje
	0						\ begin met getal ivm drop
	begin
		drop random dup vrij?
	until
	;

: P				( nr -- )
	depth 0= if 1 then
	dup to seed
	clrTegel
	#steentjes 0 ?do 
		zoek 				\ zoek een geldig steentje
        loc *bis			\ en zet bitje in tegelmap
	loop
	cr ." Ontwerp voor tegel " . 
	;
	
: .P		( hor,vert -- )	
	0 ?do					\ tegels verticaal
		cr
		#ver 0 ?do				\ rij die wordt afgedrukt
			i 
			over 0 ?do			\ tegels horizontaal
				."  "
				tc bgc
				#hor 0 ?do		\ steentje in de rij
					dup #ver * i + 
					loc bit* if 
						sc bgc
					    ."  " 
						tc bgc
					else 
					    ."  " 
					then
				loop
				\ vc bgc
				default
			loop
			drop cr
		loop
	loop
	drop
	;
	
: TEGELTEST		( startnr, #tegels -- )
	over + swap cr ." test " .s ?do
		i p
		2 1 .p
		250 ms
	loop
	;
	
: KLEURPALET	( -- )
	cr ."    0 1 2 3 4 5 6 7 8 9 A B C D E F" cr
	10 0 ?do
		 ."  " i dup . 
		10 0 ?do
			dup 10 * i + bgc ."   "
		loop
		drop
		default cr
	loop
	;